plugins {
    id "com.android.application"
}

def ciVersionCode = providers.gradleProperty("ciVersionCode").getOrNull()
def ciVersionName = providers.gradleProperty("ciVersionName").getOrNull()
def sharedDebugKeystore = file("signing/bible-daily-debug.keystore")

android {
    namespace "com.bibliadiaria.app"
    compileSdk 35

    signingConfigs {
        sharedDebug {
            storeFile sharedDebugKeystore
            storePassword "android"
            keyAlias "androiddebugkey"
            keyPassword "android"
        }
    }

    defaultConfig {
        applicationId "com.bibliadiaria.app"
        minSdk 23
        targetSdk 35
        versionCode ciVersionCode != null ? ciVersionCode.toInteger() : 1
        versionName ciVersionName != null ? ciVersionName : "1.0"
    }

    buildTypes {
        debug {
            if (sharedDebugKeystore.exists()) {
                signingConfig signingConfigs.sharedDebug
            }
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"
}